一般情況下，如果我們想了解股市行情，必須登錄專業股票網站，輸入公司代碼才能看到具體股價。其實，利用XMLHTTP協議，我們每個人都可以在自己的個人網站中提供股市行情詳細情況查詢服務，本文介紹了如何使用ASP、VbScript結合XMLhttp編程來實現這個功能。
一、原理
原理非常簡單，在很多大型網站上都有實時更新的股市行情信息，我們通過自己的ＷＥＢ服務器發送出XMLHTTP命令訪問雅虎財經站點的股市行情數據庫服務器，從數據庫中查詢我們所需要的內容，然後通過ＡＳＰ組合成網頁回送給客戶端。
同時，我們使用XMLHttp協議實現客戶端網頁無刷新效果以及向服務端提出檢索數據的要求。
XMLHTTP允許你打開一個到任意服務器上的HTTP連接，發送一些數據和取回一些數據。並且所有的這一切都是在很少的幾段腳本中就能夠實現。使用XMLHTTP對象通常是進行XML數據交換，但其他格式的數據也是允許的。
在商業程序中的運用這種交換類型的標准模式是客戶端發送一個文本字符串到服務端，然後服務端將這個字符串裝載入一個XMLDOM對象中並且解釋它，然後返回一段Html給客戶端，或則是另外一段XML代碼給客戶端讓客戶端的浏覽器自己解釋。在這種方式下，對於信息的傳遞來說是非常有效的形式，尤其是當你使用DHtml允許你根據返回信息動態顯示時。
具體流程為：客戶端通過XMLhttp提出股票行情查詢要求-->ＷＥＢ服務器中的ASP偵聽頁接受請求後使用XMLhttp向股市行情數據庫服務器發送檢索命令-->數據庫執行查詢操作，返回結果給我們自己的ＷＥＢ服務器（Html形式）-->ＷＥＢ服務器接收到內容後，過濾掉ＨＴＭＬ多余部分，挑選出純股票數據，組合後將結果傳送給客戶端->客戶端浏覽器使用vbscript顯示出來。
二、ASP XMLHttp編程簡述
1、客戶端dns2.htm頁面：
<script language="vbscript">
Sub submit1_onmouseup
Dim objXML, objXSL, objFSO,strFile, strFileName, strXSL,strURL, theString,TheForm
Set TheForm = Document.Wordfind
window.status="正在檢索數據···"
strURL="dns2.ASP" ' 服務器偵聽頁地址
Set objXML = CreateObject("Microsoft.XMLHTTP") '創建MS的XMLHTTP組件
stra = "submit=submit&fqdn="&TheForm.webname.value
objXML.Open "post",strURL,false '采用Post提交方式；
objXML.setrequestheader "content-length",len(stra)
objXML.setrequestheader "content-type","application/x-www-form-urlencoded"
objXML.send stra ' 發送信息
xmlGet = objXML.responsebody '稍等片刻後，得到服務器端傳回來的結果；
xmlGet = bytes2bstr(XMLGet) '將單字節轉換成文本格式函數，源程序可以下面的dns2.ASP程序中找到；
TheForm.comments.value=XMLGet
Set objXML = Nothing
end sub
</script>
<html><head><title>XMLHTTP之股票行情篇</title><meta http-equiv="Content-Type" content="text/Html; charset=gb2312">
</head>
<body bgColor=#a1bae6>
<table border="0" cellpadding="0" cellspacing="0" width="100%">
<tr>
<td width="100%" align=center>
<form method="post" name=Wordfind onsubmit="Javascript:return false">
<FONT color=#002e5b face=geneva,arial,sans-serif size=2>
<B>請選擇股票名稱（美國納斯達克）</B></FONT>
<FONT color=#002e5b face=geneva,arial,sans-serif size=2><B>:<br>
<select name=webname style="HEIGHT: 22px; WIDTH: 80px">
<option value="^IXIC">納斯達克</option><option value="ASIA">亞信</option>
<option value="CHINA">中華網</option> <option value="NTES">網易</option>
<option value="SINA">新浪網</option> <option value="SOHU">搜狐</option>
</select><input type="submit" value="查詢" id=Submit1 name=Submit1></B>
<TEXTAREA name=comments readonly rows=10 cols=76 ></TEXTAREA>
</form></td></tr></table></body></Html>
2、服務器端dns2.ASP程序：
<%
dim XMLGet
XMLGet=""
if len(trim(Request.form("fqdn"))) > 1 then
Dim objXML, objXSL, objFSO
Dim strFile, strFileName, strXSL
Dim strURL, theString
'股市行情數據庫服務器的地址
strURL="http://cn.finance.yahoo.com/q?s="+trim(Request.form("fqdn"))+"&d=2b"
Set objXML = CreateObject("Microsoft.XMLHTTP") '創建MS的XMLHTTP組件
objXML.Open "get", strURL, False
objXML.Send ' 發送信息
xmlGet = objXML.responsebody '稍等片刻後，得到股市行情數據服務器端傳回來的結果；
xmlGet = bytes2bstr(XMLGet) '轉換成文本格式函數，可以源程序中找到；
'過濾無用的Html成分，挑選出股票具體信息；
strFind1 = instr(1,XMLGet,"最後交易",1)+8
strFind2 = instr(strFind1,XMLGet,"<b>",1)+3
strFind3 = instr(strFind2,XMLGet,"</b></td>",1)
xmlGet1="最後交易："+mid(XMLGet,strFind2,strFind3-strFind2)+chr(13)+chr(10) '最後交易價
strFind1 = instr(1,XMLGet,"漲跌",1)+4
strFind2 = instr(strFind1,XMLGet,"<font color=",1)+19
strFind3 = instr(strFind2,XMLGet,"</font>",1)
xmlGet2="漲跌："+mid(XMLGet,strFind2,strFind3-strFind2)+chr(13)+chr(10) '漲跌
Set objXML = Nothing
end if
response.write trim(Request.form("fqdn"))+"的股市行情："+chr(13)+chr(10)+xmlGet1+XMLGet2
function bytes2bstr(vin)
strreturn = ""
for i = 1 to lenb(vin)
thischarcode = ascb(midb(vin,i,1))
if thischarcode < &h80 then
strreturn = strreturn & chr(thischarcode)
else
nextcharcode = ascb(midb(vin,i+1,1))
strreturn = strreturn & chr(clng(thischarcode) * &h100 + cint(nextcharcode))
i = i + 1
end if
next
bytes2bstr = strreturn
end function
%>
在上述過程中，可以發現我們自己的ＷＥＢ服務器中的ＡＳＰ程序其實只起到一個中間傳遞的作用，在實際應用中，也可以省去這個中間層，使用vbscript通過XMLhttp直接向股市行情數據庫發送和接收數據。不過這樣的話，可能會因為ＩＥ中“通過（其它）域訪問數據資源”被禁用（默認）而引起權限不夠導致無法執行，所以該省去ＡＳＰ中間層的方法並不太通用。
本程序在基於Windows2000平台的IIS5.0和IE6.0上運行通過。實際使用過程中，可以把上述代碼拷貝到自己網頁中，經過簡單的頁面編輯，就可在自己的網頁中增加在頁面無閃爍情況下的股票信息查詢功能了，初看上去，還真的有點象專業的證券服務商網站提供的服務了。
查看源程序:
http://www.ccw.com.cn/htm/center/prog/02_7_24_4_2.ASP